I know this thread is two years old, but I'd like to share my macro here, as I believe I've managed to create a queueable version of the Summon Eos / Summon Seraph / Consolation macro. I learned this technique from a Japanese blog post. I've also seen a similar macro in the Chinese BBS. FFXIVMacrology (English version) was also helpful to me.

Prerequisite:
- The macro below is assigned to scholar 1 1 and scholar 2 1.

Caution:
- This will overwrite scholar hotbar 1.

Drawbacks:
- You need to press the key twice for the action to queue.
- You need to run another macro during <wait.60> to prevent "Summon Eos".

Macro:
/action "Summon Seraph"
/hotbar action "Summon Seraph" 1 1
/action "Summon Seraph" <p> <wait>
/hotbar copy scholar 2 scholar 1
/petaction "Guard" <p> <wait.60>
/action "Summon Eos"
/hotbar action "Summon Eos" 1 1 <wait>
/hotbar copy scholar 2 scholar 1
/macroicon "Summon Seraph"

How this macro works:
- This macro uses a pseudo-conditional trick. This can also be applied to other non-chat text commands that accept placeholders as subcommands. If <wait> is used with a placeholder, the wait only works when the placeholder is valid.
- If Eos is summoned: <p> is valid and first wait works, so the normal version of "Summon Seraph" will be assigned to the hotbar before the second execution. The second wait delays "Summon Eos" by 60 seconds.
- If Seraph is summoned: The behaviour is the same as above except the action changes to "Consolation".
- If neither Eos nor Seraph is summoned: <p> is invalid and the first and second waits are skipped. The third wait always works, ensuring that the normal version of "Summon Eos" will be assigned to the hotbar before the second execution.

Comments:
- Note that since "Summon Eos" is a spell and "Summon Seraph" is an ability, their queueing window times differ.
- Adjust the hotbar and slot numbers to fit your setup.
- To lengthen the duration of the wait before "Summon Eos", repeat the fifth line of the macro.
- I recommend creating another macro that includes /hotbar copy in case the copy command doesn't work (e.g., you get wiped before copying).